Groovy 2d arrays

Question

I have 3 arrays, l1[,,,,], l2[,,,,] and l3[,,,,]. Each of which has 5 characters in it.

e.g. l1["A","B","C","D","E"]

The 2d array is made up of these

screen = [l1[],l2[],l3[]]

so it will look as so:

screen = [[,,,,],[,,,,],[,,,,]]

How can I iterate through this array?

do I call screen[5]? or screen[l1[5]]?

can I:

for (i in 1..15){

 println screen[i]
}

please help!!!

How can I iterate in the array and call different parts, e.g. the 1st element of each sub array?

Thanks

Answer 1

So, given:

List l1 = ['A', 'B', 'C', 'D', 'E']
List l2 = ['a', 'b', 'c', 'd', 'e']
List l3 = ['1', '2', '3', '4', '5']

List screen = [ l1, l2, l3 ]

To iterate all the elements, you could do:

3.times { y ->
    5.times { x ->
        println screen[ y ][ x ]  
    }
}

Or, you could use mod and intdiv to work out x and y positions:

15.times { p ->
    def x = p % 5
    def y = p.intdiv( 5 )
    println screen[ y ][ x ]
}

Or, if you want the first element from each sub-list, you can do:

println screen*.head()

Or, say you want the 3rd element from each sub-list:

println screen*.getAt( 2 )

Alternatively, you could put all the items into a one-dimensional List:

def inlineScreen = [ *l1, *l2, *l3 ]

Then access then by:

15.times { p ->
    println inlineScreen[ p ]
}

or:

def x = 1, y = 1
println inlineScreen[ x + y * 5 ]

Or, if it is important that you always want to get the elements together (ie, you always want the second elements from all the arrays together), then you could do:

// groupedScreen == [['A', 'a', '1'], ['B', 'b', '2'], ['C', 'c', '3'], ['D', 'd', '4'], ['E', 'e', '5']]
def groupedScreen = [ l1, l2, l3 ].transpose()

Then, to get the 3rd elements, you can just do:

groupedScreen[ 2 ]