Gradle retrofit failed to resolve

Question

This is my first time trying to use gradle with an android project. I would like to add retrofit to my project but it keeps telling me.

Failed to resolve: com.squareup.retrofit:retrofit:1.9.0

Failed to resolve: com.squareup.okhttp:2.2.0

However google play services works perfectly.

My gradle file is as follows:

apply plugin: 'com.android.application'

android {
  compileSdkVersion 21
  buildToolsVersion "21.1.2"

  defaultConfig {
    applicationId "test.gradel"
    minSdkVersion 14
    targetSdkVersion 21
    versionCode 1
    versionName "1.0"
 }
 buildTypes {
    release {
        minifyEnabled false
        proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
    }
 }
}

dependencies {
  compile fileTree(include: ['*.jar'], dir: 'libs')
  compile 'com.android.support:appcompat-v7:21.0.3'
  compile 'com.google.android.gms:play-services:6.5.87'
  compile group: "com.squareup.retrofit", name: "retrofit", version: "1.9.0"
  compile group: "com.squareup.okhttp", name: "okhttp", version: "2.2.0"
}

buildscript {
  repositories {
    jcenter()
  }

  dependencies {
    classpath 'com.android.tools.build:gradle:1.1.2'
  } 
}

Any help would be greatly appreciated.

Thanks

Answer 1

The problem was fixed by creating a higher level build.gradle file and moved the following code into it.

buildscript {
  repositories {
    jcenter()
  }
  dependencies {
    classpath 'com.android.tools.build:gradle:1.1.2'
  }
}

allprojects {
  repositories {
    jcenter()
  }
}

Answer 2

You have to specify where you can find these artifacts. You have to add a repository block in your script.

You have to add this to your build.gradle

 repositories {
    mavenCentral()
 }

or

 repositories {
    jcenter()
 }

The Google play services library works because it is located in the Google Repository, which is downloaded with SDK Manager.