Google Docs Export CSV with double quotes

Question

I have a Google spreadsheet that I need to export and have every field contained in double quotes "field" but at the moment it doesn't not do this.

Is there an easy way to achieve this without resorting to manually editing hundreds of lines?

Max

Answer 1

You can use from excel too using appropiate macro like this:

Sub QuoteCommaExport()

   ' Dimension all variables.

   Dim DestFile As String

   Dim FileNum As Integer

   Dim ColumnCount As Integer

   Dim RowCount As Integer



   ' Prompt user for destination file name.

   DestFile = InputBox("Enter the destination filename" & Chr(10) & "(with complete path):", "Quote-Comma Exporter")



   ' Obtain next free file handle number.

   FileNum = FreeFile()



   ' Turn error checking off.

   On Error Resume Next



   ' Attempt to open destination file for output.

   Open DestFile For Output As #FileNum



   ' If an error occurs report it and end.

   If Err <> 0 Then

      MsgBox "Cannot open filename " & DestFile

      End

   End If



   ' Turn error checking on.

   On Error GoTo 0



   ' Loop for each row in selection.

   For RowCount = 1 To Selection.Rows.Count



      ' Loop for each column in selection.

      For ColumnCount = 1 To Selection.Columns.Count



         ' Write current cell's text to file with quotation marks.

         Print #FileNum, """" & Selection.Cells(RowCount, ColumnCount).Text & """";



         ' Check if cell is in last column.

         If ColumnCount = Selection.Columns.Count Then

            ' If so, then write a blank line.

            Print #FileNum,

         Else

            ' Otherwise, write a comma.

            Print #FileNum, ";";

         End If

      ' Start next iteration of ColumnCount loop.

      Next ColumnCount

   ' Start next iteration of RowCount loop.

   Next RowCount



   ' Close destination file.

   Close #FileNum

End Sub

Answer 2

I found that you can achieve this by using Open Office. From their you can define your own separators and surrounding characters.

When saving/exporting as a CSV check the box saying define my own characters.