Global signingConfig for multi-project build

Question

I'm using project structure like this:

root
  |--build.gradle
  |--settings.gradle
  |
  |--child1
  |    |--build.gradle
  |
  |--child2
       |--build.gradle

In both child projects build.gradle contains the following:

apply plugin: 'android'

...

android {
    ...

    signingConfigs {
        release {
            storeFile file("release.keystore")
            storePassword "pass"
            keyAlias "alias"
            keyPassword "pass"
        }
    }

    buildTypes {
        release {
            signingConfig signingConfigs.release
        }
    }
    ...
}

How can I move signingConfigs part to the root project to reduce code duplication?

Answer 1

I have try this code and it works. Be aware do not use signingConfigs in android-library project.

subprojects {

afterEvaluate {
    def isAndroidProject = project.plugins.hasPlugin('android')
    def isLibraryProject = project.plugins.hasPlugin('android-library')
    if (isAndroidProject || isLibraryProject) {
        android {
            compileSdkVersion 19
            buildToolsVersion 19.0.1

            compileOptions {
                sourceCompatibility JavaVersion.VERSION_1_7
                targetCompatibility JavaVersion.VERSION_1_7
            }

            if (isAndroidProject) {
                signingConfigs {
                    release {
                        storeFile file("${rootDir}/platform.keystore")
                        storePassword "android"
                        keyAlias "platform"
                        keyPassword "android"
                    }
                }

                buildTypes {
                    release {
                        signingConfig signingConfigs.release
                        minifyEnabled true
                        proguardFiles getDefaultProguardFile('proguard-android.txt'), "${project.projectDir}/proguard-project.txt"
                    }
                }

                android.applicationVariants.all { variant ->
                    variant.outputs.each  { output ->
                        def buildType = variant.buildType.name
                        if (buildType.equals('release')) {
                            def fileName = "${project.name}.apk";
                            output.outputFile = new File(output.outputFile.parent, fileName)

                            output.assemble.doLast {
                                copy {
                                    from output.outputFile.getAbsolutePath()
                                    into "../apks/"
                                }
                            }
                        }
                    }
                }
            }
        }
    }
}