Faster way to check for element in array?

Question

This function does the same as exists does with hashes.

I plan on use it a lot.

Can it be optimized in some way?

my @a = qw/a b c d/;

my $ret = array_exists("b", @a);

sub array_exists {
    my ($var, @a) = @_;

    foreach my $e (@a) {
        if ($var eq $e) {
            return 1;
        }
    }
    return 0;
}

Answer 1

If you have to do this a lot on a fixed array, use a hash instead:

 my %hash = map { $_, 1 } @array;

 if( exists $hash{$key} ) { ... }

Some people reach for the smart match operator, but that's one of the features that we need to remove from Perl. You need to decide if this should match, where the array hold an array reference that has a hash reference with the key b:

use 5.010;

my @a = (
    qw(x y z),
    [ { 'b' => 1 } ],
    );

say 'Matches' if "b" ~~ @a; # This matches

Since the smart match is recursive, if keeps going down into data structures. I write about some of this in Rethinking smart matching.

Answer 2

You can use smart matching, available in Perl 5.10 and later:

if ("b" ~~ @a) {
    # "b" exists in @a
}

This should be much faster than a function call.