Conflict with dependency 'com.android.support:support-annotations'. Resolved versions for app (23.3.0) and test app (23.1.1) differ

Question

I came across this exception while adding espresso to an android project. I already try the link that comes with this exception

**Conflict with dependency 'com.android.support:support-annotations'. Resolved versions for app (23.3.0) and test app (23.1.1) differ**

also I add the following line according to other thread I found

**androidTestCompile 'com.android.support:support-annotations:23.1.0'**

But the problem still persist. I am using the following configurations:

buildToolsVersion "23.0.2"

androidTestCompile 'com.android.support.test:runner:0.5'
androidTestCompile 'com.android.support.test:rules:0.5'
androidTestCompile 'com.android.support.test.espresso:espresso-core:2.2.2'

Any ideas, thanks.

Answer 1

This solve the problem 'Resolved versions for app (24.0.0-beta1) and test app (23.0.1) differ' for me.

android{    
    configurations.all {
        resolutionStrategy.force 'com.android.support:support-annotations:23.0.1'
    }
}

And do not forget to add following code, if you want to run the AndroidTest

 defaultConfig {
    testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
}

Answer 2

dependencies {
    //...

    // Solves "versions for app (23.3.0) and test app (23.1.1) differ"
    androidTestCompile 'com.android.support:support-annotations:23.3.0'

    // Android JUnit Runner
    androidTestCompile 'com.android.support.test:runner:0.5'
    // JUnit4 Rules
    androidTestCompile 'com.android.support.test:rules:0.5'
}

Answer 3

Nowadays when you create a new project on Android Studio, it adds this dependency by default:

androidTestCompile('com.android.support.test.espresso:espresso-core:2.2.2', {
    exclude group: 'com.android.support', module: 'support-annotations'
})

The exclude section is probably to avoid the conflict mentioned in the question. I also faced this issue when trying to add runner:0.5 and rules:0.5 dependencies. My solution was to apply the same piece of code above on them:

androidTestCompile ('com.android.support.test:runner:0.5', {
    exclude group: 'com.android.support', module: 'support-annotations'
})

androidTestCompile ('com.android.support.test:rules:0.5', {
    exclude group: 'com.android.support', module: 'support-annotations'
})

It works for me. Hope it helps.

Answer 4

annotation library is used by all three dependancies rules:0.5', runner:05 and espresso-core:2.2.2, so following worked for me

androidTestCompile 'com.android.support.test:runner:0.5', {
    exclude group: 'com.android.support', module: 'support-annotations'
}
androidTestCompile 'com.android.support.test:rules:0.5', {
    exclude group: 'com.android.support', module: 'support-annotations'
}
androidTestCompile 'com.android.support.test.espresso:espresso-core:2.2.2', {
    exclude group: 'com.android.support', module: 'support-annotations'
}