Compare two vectors in clojure no matter the order of the items

Question

I want to compare two vectors and find out if the items they have are the same no matter the order the items are in.

So..

right now in clojure:

(= [1 2 3] [3 2 1]) ;=> false

I want:

(other_fun [1 2 3] [3 2 1]) ;=> true

(other_fun [1 2 3 4] [3 2 1]) ;=> false

I could not find a containsAll like in java

Answer 1

If you do care about duplicates, you can compare their frequency maps. These are maps with each collection element as a key and number of occurrences as a value. You create them using standard function frequencies, like in given examples.

Different order, same number of duplicates:

(= (frequencies [1 1 2 3 4])(frequencies [4 1 1 2 3]))

evaluates true.

Different order, different number of duplicates:

(= (frequencies [1 1 2 3 4])(frequencies [4 1 2 3]))

evaluates false.

So, you can write a function:

(defn other_fun [& colls]
  (apply = (map frequencies colls)))

Answer 2

If you don't care about duplicates, you could create sets from both vectors and compare these:

(= (set [1 2 3]) (set [3 2 1])) ;=> true

As a function:

(defn set= [& vectors] (apply = (map set vectors)))