Can Terraform watch a directory for changes?

Question

I want to monitor a directory of files, and if one of them changes, to re-upload and run some other tasks. My previous solution involved monitoring the individual files, but this is error-prone as some files may be forgotten:

resource "null_resource" "deploy_files" {    
  triggers = {
    file1 = "${sha1(file("my-dir/file1"))}"
    file2 = "${sha1(file("my-dir/file2"))}"
    file3 = "${sha1(file("my-dir/file3"))}"
    # have I forgotten one?
  }

  # Copy files then run a remote script.
  provisioner "file" { ... }
  provisioner "remote-exec: { ... }
}

My next solution is to take a hash of the directory structure in one resource, and use this hash as a trigger in the second:

resource "null_resource" "watch_dir" {
  triggers = {
    always = "${uuid()}"
  }

  provisioner "local-exec" {
    command = "find my-dir  -type f -print0 | xargs -0 sha1sum | sha1sum > mydir-checksum"
  }
}


resource "null_resource" "deploy_files" {    
  triggers = {
    file1 = "${sha1(file("mydir-checksum"))}"
  }

  # Copy files then run a remote script.
  provisioner "file" { ... }
  provisioner "remote-exec: { ... }
}

This works okay, except changes to mydir-checksum are only picked up after the first apply. So I need to apply twice, which isn't great. It's a bit of a kludge.

I can't see a more obvious way to monitor an entire directory for changes in content. Is there a standard way to do this?

Answer 1

You can use the "archive_file" data source:

data "archive_file" "init" {
  type        = "zip"
  source_dir = "data/"
  output_path = "data.zip"
}

resource "null_resource" "provision-builder" {
  triggers = {
    src_hash = "${data.archive_file.init.output_sha}"
  }

  provisioner "local-exec" {
    command = "echo Touché"
  }
}

The null resource will be reprovisioned if and only if the hash of the archive has changed. The archive will be rebuilt during refresh whenever the contents of source_dir (in this example data/) change.