Build Maven plugins using Gradle

Question

I am thinking about moving to Gradle. I do, however, have some Maven plugins that will need to be supported for the foreseeable future.

Is there a way to build Maven plugins using Gradle?

Answer 1

Here's something that worked for me:

• After compiling plugin's sources generate project's POM: "install.repositories.mavenInstaller.pom.writeTo( 'pom.xml' )"
• Patch POM generated and provide plugin's coordinates and correct destination directories
• Run "mvn org.apache.maven.plugins:maven-plugin-plugin:3.2:descriptor"

This way "build/classes/main/META-INF/maven/plugin.xml" is created and then packed properly by jar task, which is all that's needed for a jar file to become a Maven plugin, AFAIK. Also, I believe, "maven-plugin-annotations" should be used in a plugin.

task pluginDescriptor( type: Exec ) {
    commandLine 'mvn', '-e', '-B', 'org.apache.maven.plugins:maven-plugin-plugin:3.2:descriptor'
    doFirst {
        final File pom = project.file( 'pom.xml' )
        install.repositories.mavenInstaller.pom.writeTo( pom )
        assert pom.file, "[$pom.canonicalPath] was not created"

        pom.text = pom.text.
            replace( '<groupId>unknown</groupId>',             "<groupId>${project.group}</groupId>" ).
            replace( '<artifactId>empty-project</artifactId>', "<artifactId>${project.name}</artifactId>" ).
            replace( '<version>0</version>',                   """
                                                              |<version>${version}</version>
                                                              |  <packaging>maven-plugin</packaging>
                                                              |  <build>
                                                              |    <directory>\${project.basedir}/build</directory>
                                                              |    <outputDirectory>\${project.build.directory}/classes/main</outputDirectory>
                                                              |  </build>
                                                              |""".stripMargin().trim())
    }
    doLast {
        final  pluginDescriptor = new File(( File ) project.compileGroovy.destinationDir, 'META-INF/maven/plugin.xml' )
        assert pluginDescriptor.file, "[$pluginDescriptor.canonicalPath] was not created"
        println "Plugin descriptor file:$pluginDescriptor.canonicalPath is created successfully"
    }
}

project.compileGroovy.doLast{ pluginDescriptor.execute() }