Behaviour of SELECT @Var and SET @Var in T-SQL when dealing with NULLs

Question

Everyday I learn something new, it seems :) Can someone please explain to me the rationale behind the following code behavior:

DECLARE @A INT

SET @A = 15
SET @A = (SELECT ValueThatDoesntExist FROM dbo.MyTable WHERE MyColumn = 'notfound')

SELECT @A
-- Rsultset is NULL

SET @A = 15
SELECT @A = ValueThatDoesntExist FROM dbo.MyTable WHERE MyColumn = 'notfound'

SELECT @A
-- Resultset is 15

From what I see, SET changes the value of the variable if the resultset is NULL, while SELECT doesn't. Is this normal ANSI behavior or is it T-SQL specific?

Of, course, if I do SELECT @A = NULL, the assignment happens correctly.

Answer 1

The first version sets A to the result of a query:

SET @A = (SELECT ValueThatDoesntExist FROM dbo.MyTable WHERE MyColumn = 'notfound')

Basically the select in in scalar context, and if it doesn't find a row, it evaluates to null.

The second version sets A for each row in the result set:

SELECT @A = ValueThatDoesntExist FROM dbo.MyTable WHERE MyColumn = 'notfound'

Since there are no rows, A is never assigned to. Another example:

declare @a int

select  @a = i
from    (
        select  1
        union all select 2
        union all select 3
        ) as SubQueryAlias(i)
order by
        i

select  @a

This will assign 3 values to @a. The last one assigned is 3, so that's what the query prints.

Answer 2

Well the select returns no rows. So practically there is not assignment.

While the set will have a null as a result.