Android Studio - get build machine's IP address into Android app

Question

During app development, I want the app to connect back to the machine it was built on (over Wifi).

As we have multiple developers, this will be a different IP address for each developer.

How can I do this?

(Some developers use AndroidStudio on Windows 7, other AndroidStudio on Ubuntu 14.04LTS.)

Answer 1

This is my solution. Really useful to keep a clean git status.

/**
 * Find the first LAN address of the development machine.
 */
def getDevHost = { ->
    def defaultDevHost = InetAddress.getLocalHost()
            .getCanonicalHostName()

    return NetworkInterface.getNetworkInterfaces()
            .findResult(defaultDevHost) {
        def ifOk = it.isUp() &&
                !it.isVirtual() &&
                !it.isPointToPoint() &&
                !it.isLoopback() &&
                !it.getName().startsWith("br-") // 

        if (ifOk)
            return it.getInetAddresses().find {
                it instanceof Inet4Address &&
                        !it.isLoopbackAddress()
            }
        else
            return null
    }
}

I'm using it for a single buildType of the project:

android {
  // ...

  buildTypes {
    // ...

    dev {
      // ...
      buildConfigField "String", "BACKEND_URL", "\"http://${getDevHost()}:9000/\""
    }
  }
}