An error equivalent for process.text?

Question

You can get the entire output stream by using .text:

def process = "ls -l".execute()
println "Found text ${process.text}"

Is there a concise equivalent to get the error stream?

Answer 1

You can use waitForProcessOutput which takes two Appendables (docs here)

def process = "ls -l".execute()
def (output, error) = new StringWriter().with { o -> // For the output
  new StringWriter().with { e ->                     // For the error stream
    process.waitForProcessOutput( o, e )
    [ o, e ]*.toString()                             // Return them both
  }
}
// And print them out...
println "OUT: $output"
println "ERR: $error"

Answer 2

Based on tim_yates answer, I tried it on Jenkins and found this issue with multiple assignment: https://issues.jenkins-ci.org/browse/JENKINS-45575

So this works and it is also concise:

def process = "ls -l".execute()
def output = new StringWriter(), error = new StringWriter()
process.waitForProcessOutput(output, error)
println "exit value=${process.exitValue()}"
println "OUT: $output"
println "ERR: $error"