Perl assigning @ARGV array to a variable

Question

When I assign the Perl @ARGV array to a variable, if I don't use the quotes, it gives me the number of strings in the array, and not the strings in the array.

What is this called - I thought it was dereferencing, but it is not. Right now I am calling it one more thing I need to memorize in Perl.

#!/usr/bin/perl

use strict ;
use warnings;

my $str = "@ARGV" ;
#my $str = @ARGV ;
#my $str = 'geeks, for, geeks';
my @spl = split(', ' , $str);

foreach my $i (@spl) {
        print "$i\n" ;
}

Answer 1

If you assign an array to a scalar in Perl, you get the number of elements in the array.

my @array = (1, 1, 2, 3, 5, 8, 13);

my $scalar = @array; # $scalar contains 7

This is known as "evaluating an array in scalar context".

If you expand an array in a double-quoted string in Perl, you get the elements of the array separated by spaces.

my @array = (1, 1, 2, 3, 5, 8, 13);

my $scalar = "@array"; $scalar contains '1 1 2 3 5 8 13'

This is known as "interpolating an array in a double-quoted string".

Actually, in that second example, the elements are separated by the current contents of the $" variable. And the default value of that variable is a space. But you can change it.

my @array = (1, 1, 2, 3, 5, 8, 13);

$" = '+';
my $scalar = "@array"; $scalar contains '1+1+2+3+5+8+13'

To store a reference to the array, you either take a reference to the array.

my $scalar = \@array;

Or create a new, anonymous array using the elements of of the original array.

my $scalar = [ @array ];

Because we don't know what you are actually trying to do, we can't recommend which of these is the best approach.

Answer 2

Perl works by context. The one that you see here is scalar versus array context. In scalar context, you want one thing, so Perl gives you the one thing the probably makes sense. Recognize the context and you can probably suss out what's going on.

When you have a scalar on the left side of an assignment, you have scalar context because you want to end up with one thing:

my $one_thing = ...

Put an array on the right side, and you have an array in scalar context. The design of Perl decided that the most common thing people probably want in that case is the number of elements:

my $one_thing = @array;

This works with some other builtins too. The localtime builtin returns a single string in scalar context (a timestamp):

my $uid = localtime;  # Tue Mar 17 11:39:47 2020

But, in array context, you want possibly multiple things (where that could be two, or one, or zero, or ten thousand, or...). In that case, localtime returns a list of things:

my ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
    localtime();

You already know some of this though, probably. The + operator uses its operands as numbers, but the . operator uses them as strings:

my $sum = '123' + 14;
my $string = '123' . 14;

Perl's philosophy is that it is going to try to do what the verbs (operators, builtins, functions) are trying to do, not what the nouns (variable or value type) might imply. Many languages tell the verbs what to do based on the nouns, so fitting Perl into one of those mental modules usually doesn't work out. You don't have to memorize a lot; I've been doing this quite awhile and I still refer to the docs often.

We go through a lot of this philosophical explanation in Learning Perl.