using Regexp::Grammars what does (*COMMIT) do?

Question

I'm looking at an example for Regexp::Grammars. The example has a comment around *COMMIT stating about how it will improve the error messages. I can't find any documentation on *COMMIT. What does it do ? I've included part of the example below:

    use Regexp::Grammars;
qr{ 
    \A 
    <Answer>
    (*COMMIT)   # <-- Remove this to see the error messages get less accurate
    (?:
        \Z
    |
        <warning: (?{ "Extra junk after expression at index $INDEX: '$CONTEXT'" })>
        <warning: Expected end of input>
        <error:>
    )

    <rule: Answer>  
        <[_Operand=Mult]>+ % <[_Op=(\+|\-)]>
            (?{ $MATCH = shift @{$MATCH{_Operand}};
                for my $term (@{$MATCH{_Operand}}) {
                    my $op = shift @{$MATCH{_Op}};
                    if ($op eq '+') { $MATCH += $term; }
                    else            { $MATCH -= $term; }
                }
            })
      |
        <error: Expected valid arithmetic expression>

Answer 1

(*COMMIT) is documented in perlre.

(*COMMIT) is useful in causing an whole alternation to fail when one of the branch fails after reaching a certain point.

$ perl -E'
   say "$_: ", /
      ^
      (?: a (*COMMIT) b
      |   c (*COMMIT) d
      |   . z
      )
   /sx ?1:0
      for qw( ab cd az yz );
'
ab: 1
cd: 1
az: 0
yz: 1

You could have written the following, but it could be far less efficient and far harder to write in more complex examples:

/
   ^
   (?: a b
   |   c d
   |   [^ac] z
   )
/x