How to list all directories from within directory in jenkins pipeline script

Question

I want to get all directories present in particular directory from jenkins pipeline script.

How can we do this?

Answer 1

If you want a list of all directories under a specific directory e.g. mydir using Jenkins Utility plugin you can do this:

Assuming mydir is under the current directory:

 dir('mydir') {
   def files = findFiles() 
 
   files.each{ f -> 
      if(f.directory) {
        echo "This is directory: ${f.name} "
      }
   }
 }

Just make sure you do NOT provide glob option. Providing that makes findFiles to return file names only.

More info: https://jenkins.io/doc/pipeline/steps/pipeline-utility-steps/

Answer 2

I didn't find any plugin to list folders, so I used sh/bat script in pipeline, and also this will work irrespective of operating system.

pipeline {
  stages {
    stage('Find all fodlers from given folder') {
      steps {
        script {
                    
          def foldersList = []
                    
          def osName = isUnix() ? "UNIX" : "WINDOWS"
          echo "osName: " + osName
    
          echo ".... JENKINS_HOME: ${JENKINS_HOME}"
    
          if(isUnix()) {
            def output = sh returnStdout: true, script: "ls -l ${JENKINS_HOME} | grep ^d | awk '{print \$9}'"
            foldersList = output.tokenize('\n').collect() { it }
          } else {
            def output = bat returnStdout: true, script: "dir \"${JENKINS_HOME}\" /b /A:D"
            foldersList = output.tokenize('\n').collect() { it }
            foldersList = foldersList.drop(2)
                     
          }
          echo ".... " + foldersList
        }            
      }
    }
  }
}