Batch FOR loop with asterisk

Question

I have this single line CMD file TEST.CMD:

for %%f in (%1 %2 %3 %4 %5 %6 %7 %8) DO ECHO %%f

If I run this:

TEST this is a test

it correctly echos each parameter on a separate line, i.e.,

this
is
a
test

However if a parameter contains asterisk it skips it. E.g.,

TEST this is a* test

Results in:

this
is
test

How do I get the parameter with an asterisk to be treated like a normal token?

Thanks.

Answer 1

The simplest method that works for most parameters is to transfer the parameters to an "array" of variables, and then use FOR /L to loop through the array. This is best achieved with delayed expansion.

This technique can process an arbitrary number of parameters - it is not limited to 9.

@echo off
setlocal

:: Transfer parameters to an "array"
set arg.cnt=1
:getArgs
(set arg.%arg.cnt%=%1)
if defined arg.%arg.cnt% (
  set /a arg.cnt+=1
  shift /1
  goto :getArgs
)
set /a arg.cnt-=1

:: Process the "array"
setlocal enableDelayedExpansion
for /l %%N in (1 1 %arg.cnt%) do echo arg %%N = !arg.%%N!